Inhalte
Index 🔎︎

# Kategorie Mathematik

Diese Kategorie enthält mathematische Funktionen für Calc. Um den Funktions-Assistenten zu öffnen, wählen Sie Einfügen - Funktion....

## AGGREGAT

Diese Funktion ergibt die Gesamtheit einer Berechnung in einem Bereich. Sie können verschiedene unten aufgelistete Gesamtheiten verwenden. Die Funktion erlaubt es, ausgeblendete Zeilen, Fehlerwerte, und die Ergebnisse der Funktionen TEILERGEBNIS und AGGREGAT bei der Berechnung nicht zu berücksichtigen.

## SUBTRAKTION

Subtrahiert mehrere Zahlen und gibt das Ergebnis zurück, ohne kleine Rundungsfehler zu beseitigen.

### FARBE

Gibt einen numerischen Wert zurück, der aus der Kombination der Werte für die drei Farben (rot, grün und blau) und dem Alpha-Kanal des RGBA-Farbsystems berechnet wird. Das Ergebnis ist abhängig vom Farbsystem des verwendeten Computers.

## SUMMEWENNS

Ergibt die Summe der Werte der Zellen in einem Bereich, die mehrere Bedingungen in mehreren Bereichen erfüllen.

## ABRUNDEN

Rundet eine Zahl gegen Null mit einer bestimmten Genauigkeit ab.

### Syntax

ABRUNDEN(Zahl; Stellen)

Ergibt Zahl, abgerundet (Richtung Null) auf die durch Stellen definierten Dezimalstellen. Wenn Stellen weggelassen wird oder Null ist, rundet die Funktion auf eine ganze Zahl ab. Wenn Stellen negativ ist, rundet die Funktion auf die nächsten 10, 100, 1000 und so weiter ab.

Diese Funktion rundet Richtung Null ab. Für Alternativen sehen sie auch AUFRUNDEN und RUNDEN.

### Beispiel

=ABRUNDEN(1,234;2) ergibt 1,23.

=ABRUNDEN(45,67;0) ergibt 45.

=ABRUNDEN(-45,67) ergibt -45.

=ABRUNDEN(987,65;-2) ergibt 900.

## ABS

Ergibt den Betrag (Absolutwert) einer Zahl.

### Syntax

ABS(Zahl)

Zahl ist die Zahl, von der der Betrag berechnet werden soll. Der Betrag einer Zahl ist ihr Wert ohne Vorzeichen.

### Beispiel

=ABS(-56) ergibt 56.

=ABS(12) ergibt 12.

=ABS(0) ergibt 0.

## ARCCOS

Ergibt den Arkuskosinus (inversen Kosinus) einer Zahl.

### Syntax

ARCCOS(Zahl)

Diese Funktion ergibt den Arkuskosinus von Zahl, das heißt den Winkel (im Bogenmaß), dessen Kosinus Zahl ergibt. Der zurückgegebene Winkel liegt zwischen 0 und Pi.

Um den Winkel in Grad zu erhalten, verwenden Sie die Funktion GRAD.

### Beispiel

=ARCCOS(-1) ergibt 3,14159265358979 (Pi im Bogenmaß)

=GRAD(ARCCOS(0,5)) ergibt 60. Der Kosinus von 60 Grad ist 0,5.

## ARCCOSHYP

Ergibt den Arkuskosinus Hyperbolicus einer Zahl.

### Syntax

ARCCOSHYP(Zahl)

Diese Funktion ergibt den Arkuskosinus Hyperbolicus von Zahl, das heißt die Zahl, deren Kosinus Hyperbolicus Zahl ist.

Zahl muss größer oder gleich 1 sein.

### Beispiel

=ARCCOSHYP(1) ergibt 0.

=ARCCOSHYP(COSHYP(4)) ergibt 4.

## ARCCOT

Ergibt den Arkuskotangens (inversen Kotangens) der gegebenen Zahl.

### Syntax

ARCCOT(Zahl)

Diese Funktion ergibt den Arkuskotangens von Zahl, das heißt den Winkel (im Bogenmaß), dessen Kotangens Zahl ist. Der zurückgegebene Winkel liegt zwischen 0 und Pi.

Um den Winkel in Grad zu erhalten, verwenden Sie die Funktion GRAD.

### Beispiel

=ARCCOT(1) ergibt 0,785398163397448 (PI/4 Bogenmaß).

=GRAD(ARCCOT(1)) ergibt 45. Der Tangens von 45 Grad ist 1.

## ARCCOTHYP

Ergibt den Arkuskotangens Hyperbolicus einer Zahl.

### Syntax

ARCCOTHYP(Zahl)

Diese Funktion ergibt den Arkuskotangens Hyperbolicus von Zahl, das heißt die Zahl, deren Kotangens Hyperbolicus Zahl ist.

Ein Fehler tritt auf, wenn Zahl zwischen -1 und 1 einschließlich liegt.

### Beispiel

=ARCCOTHYP(1,1) ergibt den Arkuskotangens Hyperbolicus von 1,1, also etwa 1,52226.

## ARCSIN

Ergibt den Arkussinus (inversen Sinus) einer Zahl.

### Syntax

ARCSIN(Zahl)

Diese Funktion ergibt den Arkussinus von Zahl, das heißt den Winkel (im Bogenmaß), dessen Sinus Zahl ist. Der zurückgegebene Winkel liegt zwischen -Pi/2 und +Pi/2.

Um den Winkel in Grad zu erhalten, verwenden Sie die Funktion GRAD.

### Beispiel

=ARCSIN(0) ergibt 0.

=ARCSIN(1) ergibt 1,5707963267949 (Pi/2 Bogenmaß).

=GRAD(ARCSIN(0,5)) ergibt 30. Der Sinus von 30 Grad ist 0,5.

## ARCSINHYP

Ergibt den Arkussinus Hyperbolicus einer Zahl.

### Syntax

ARCSINHYP(Zahl)

Diese Funktion ergibt den Arkussinus Hyperbolicus von Zahl, das heißt die Zahl, deren Sinus Hyperbolicus Zahl ist.

### Beispiel

=ARCSINHYP(-90) ergibt etwa -5,1929877.

=ARCSINHYP(SINHYP(4)) ergibt 4.

## ARCTAN

Ergibt den Arkustangens (inversen Tangens) einer Zahl.

### Syntax

ARCTAN(Zahl)

Diese Funktion ergibt den Arkustangens von Zahl, das heißt den Winkel (im Bogenmaß), dessen Tangens Zahl ist. Der zurückgegebene Winkel liegt zwischen -Pi/2 und Pi/2.

Um den Winkel in Grad zu erhalten, verwenden Sie die Funktion GRAD.

### Beispiel

=ARCTAN(1) ergibt 0,785398163397448 (PI/4 Bogenmaß).

=GRAD(ARCTAN(1)) ergibt 45. Der Tangens von 45 Grad ist 1.

## ARCTAN2

Gibt den Winkel (im Bogenmaß) zwischen der X-Achse und einer Linie vom Ursprung zum Punkt (Zahl_X|Zahl_Y) zurück.

Diese Funktion ist Teil des OpenDocument-Standards (Open Document Format for Office Applications) Version 1.2. (ISO/IEC 26300:2-2015)

### Syntax

ARCTAN2(Zahl_X; Zahl_Y)

Zahl_X ist der Wert der X-Koordinate.

Zahl_Y ist der Wert der Y-Koordinate.

Programmiersprachen verwenden für die Funktion atan2() typischerweise die umgekehrte Reihenfolge der Argumente.

ARCTAN2 gibt den Winkel (im Bogenmaß) zwischen der X-Achse und einer Linie vom Ursprung zum Punkt (Zahl_X|Zahl_Y) zurück.

### Beispiel

=ARCTAN2(-5;9) gibt 2,07789 zurück.

Um den Winkel im Gradmaß zu erhalten, wenden Sie die Funktion GRAD auf das Ergebnis an.

=GRAD(ARCTAN2(12,3;12,3)) ergibt 45. Der Tangens von 45 Grad ist 1.

LibreOffice gibt 0 für ARCTAN2(0;0) zurück.

Diese Funktion kann verwendet werden, um kartesische Koordinaten in Polarkoordinaten umzuwandeln.

=GRAD(ATAN2(-8;5)) ergibt φ = 147.9 Grad

## ARCTANHYP

Ergibt den Arkustangens Hyperbolicus einer Zahl.

### Syntax

ARCTANHYP(Zahl)

Diese Funktion ergibt den Arkustangens Hyperbolicus von Zahl, das heißt die Zahl, deren Tangens Hyperbolicus Zahl ist.

Zahl muss die Bedingung -1 < Zahl < 1 erfüllen.

### Beispiel

=ARCTANHYP(0) ergibt 0.

## AUFRUNDEN

Rundet eine von Null verschiedene Zahl mit einer festgelegten Genauigkeit auf.

### Syntax

AUFRUNDEN(Zahl; Stellen)

Ergibt Zahl, aufgerundet (weg von Null) auf die durch Stellen definierten Dezimalstellen. Wenn Stellen weggelassen wird oder Null ist, rundet die Funktion auf eine ganze Zahl auf. Wenn Stellen negativ ist, rundet die Funktion auf die nächsten 10, 100, 1000 und so weiter auf.

Diese Funktion rundet von Null weg. Für Alternativen siehe ABRUNDEN und RUNDEN.

### Beispiel

=AUFRUNDEN(1,1111;2) ergibt 1,12.

=AUFRUNDEN(1,2345;1) ergibt 1,3.

=AUFRUNDEN(45,67;0) ergibt 46.

=AUFRUNDEN(-45,67) ergibt -46.

=AUFRUNDEN(987,65;-2) ergibt 1000.

## BOGENMASS

Aus der im Textfeld eingegebenen Gradzahl wird das Bogenmaß berechnet.

### Syntax

BOGENMASS(Zahl)

Zahl ist der Winkel in Grad, der in Bogenmaß umgewandelt werden soll.

### Beispiel

=BOGENMASS(90) ergibt 1,5707963267949, das heißt Pi/2 für die Genauigkeit von Calc.

## COS

Ergibt den Konsinus des gegebenen Winkels (im Bogenmaß).

### Syntax

COS(Zahl)

Ergibt den Kosinus von Zahl, dem Winkel im Bogenmaß.

Um den Kosinus eines in Grad angegebenen Winkels zu erhalten, verwenden Sie die Funktion RAD.

### Beispiel

=COS(PI()*2) ergibt 1, den Kosinus von 2*Pi im Bogenmaß.

=COS(BOGENMASS(60)) ergibt 0,5, den Kosinus von 60 Grad.

## COSEC

Ergibt den Kosekans eines vorgegebenen Winkels (im Bogenmaß). Der Kosekans eines Winkels ist gleich 1 geteilt durch den Sinus dieses Winkels.

Diese Funktion ist seit LibreOffice verfügbar3.5

### Syntax

COSEC(Zahl)

Ergibt den Kosekans von Zahl, dem Winkel im Bogenmaß.

Um den Kosekans eines in Grad angegebenen Winkels zu erhalten, verwenden Sie die Funktion BOGENMASS.

### Beispiel

=COSEC(PI()/4) ergibt etwa 1,4142135624, das Inverse des Sinus von Pi/4 Bogenmaß.

=COSEC(BOGENMASS(30)) ergibt 2, den Kosekans von 30 Grad.

## COSECHYP

Ergibt den Kosekans Hyperbolicus einer Zahl.

Diese Funktion ist seit LibreOffice verfügbar3.5

### Syntax

COSECHYP(Zahl)

Ergibt den Kosekans Hypberbolikus von Zahl.

### Beispiel

=COSECHYP(1) ergibt etwas 0,8509181282, den Kosekans Hyperbolicus von 1.

## COSHYP

Ergibt den Kosinus Hyperbolicus einer Zahl.

### Syntax

COSHYP(Zahl)

Ergibt den Kosinus Hyperbolicus von Zahl.

### Beispiel

=COSHYP(0) ergibt 1, den Kosinus Hyperbolicus von 0.

## COT

Ergibt den Kotangens des angegebenen Winkels (im Bogenmaß).

### Syntax

COT(Zahl)

Ergibt den Kotangens von Zahl, dem Winkel im Bogenmaß.

Um den Kotangens eines in Grad angegebenen Winkels zu erhalten, verwenden Sie die Funktion BOGENMASS.

Der Kotangens eines Winkels ist gleich 1 dividiert durch den Tangens desselben Winkels.

### Beispiele:

=COT(PI()/4) ergibt 1, den Kotangens von Pi/4 Bogenmaß.

=COT(BOGENMASS(45)) ergibt 1, den Kotangens von 45 Grad.

## COTHYP

Ergibt den Kotangens Hyperbolicus einer Zahl (Winkel).

### Syntax

COTHYP(Zahl)

Ergibt den Kotangens Hyperbolicus von Zahl.

### Beispiel

=COTHYP(1) ergibt den Kotangens Hyperbolicus von 1, also etwa 1,3130.

## EUROUMRECHNEN

Rechnet ehemalige europäische nationale Währungen von und nach Euro um.

### Syntax

EUROUMRECHNEN(Wert; "Ausgangwährung"; "Zielwährung"; Volle_Genauigkeit; Zwischenergebnis_Genauigkeit)

Wert ist der Betrag der umzurechnenden Währung.

Ausgangswährung und Zielwährung sind die Währungseinheiten, aus denen beziehungsweise in die umgerechnet werden soll. Diese müssen aus einem Text bestehen, der eine offizielle Abkürzung der Währung ist (zum Beispiel "EUR"). Die (pro Euro zugrunde gelegten) Währungskurse wurden von der Europäischen Kommission festgelegt.

Volle_Genauigkeit ist ein optionaler Parameter. Wenn er fehlt oder FALSCH ist, wird das Ergebnis auf die der Zielwährung entsprechenden Stellenanzahl gerundet. Wenn Volle_Genauigkeit WAHR ist, wird das Ergebnis nicht gerundet.

Zwischenergebnis_Genauigkeit ist ein optionaler Parameter. Wenn Zwischenergebnis_Genauigkeit angeben und >=3 ist, wird das Zwischenergebnis der Umwandlung (Währung_1, EUR, Währung_2) auf diese Genauigkeit gerundet. Wenn Zwischenergebnis_Genauigkeit fehlt, wird das Zwischenergebnis nicht gerundet. Auch wenn die Zielwährung "EUR" ist, wird Zwischenergebnis_Genauigkeit verwendet, als wenn ein Zwischenergebnis berechnet würde und auf die Umwandlung EUR zu EUR angewandt.

### Beispiele

=EUROUMRECHNEN(100;"ATS";"EUR") rechnet 100 Schilling in Euro um.

=EUROUMRECHNEN(100;"EUR";"DEM") rechnet 100 Euro in Deutsche Mark um.

## EXP

Ergibt die Potenz von e mit der eingegebenen Zahl. Die Konstante e hat etwa den Wert 2,71828182845904.

### Syntax

EXP(Zahl)

Zahl ist der Exponent, mit dem e potenziert wird.

### Beispiel

=EXP(1) ergibt 2,71828182845904, die mathematische Konstante e mit der Genauigkeit von Calc.

## FAKULTÄT

Ergibt die Fakultät einer Zahl.

### Syntax

FAKULTÄT(Zahl)

Ergibt Zahl!, die Fakultät von Zahl, berechnet als 1*2*3*4* ... *Zahl.

=FAKULTÄT(0) ergibt per Definition 1.

Die Fakultät einer negativen Zahl ergibt den Fehler "Ungültiges Argument".

### Beispiel

=FAKULTÄT(3) ergibt 6.

=FAKULTÄT(0) ergibt 1.

## GANZZAHL

Die im Textfeld eingegebenen Zahl wird auf die nächstkleinere ganze Zahl abgerundet.

### Syntax

GANZZAHL(Zahl)

Ergibt Zahl, gerundet auf die nächstkleinere ganze Zahl.

Negative Zahlen werden zur nächstkleineren ganzen Zahl gerundet.

### Beispiel

=GANZZAHL(5,7) ergibt 5.

=GANZZAHL(-1,3) ergibt -2.

## GERADE

Rundet eine positive Zahl auf die nächste gerade ganze Zahl auf und eine negative Zahl auf die nächste gerade ganze Zahl ab.

### Syntax

GERADE(Zahl)

Ergibt Zahl gerundet auf die nächste gerade ganze Zahl, weg von Null.

### Beispiel

=GERADE(2,3) ergibt 4.

=GERADE(2) ergibt 2.

=GERADE(0) ergibt 0.

=GERADE(-0,5) ergibt -2.

## GGT

Ergibt den größten gemeinsamen Teiler von zwei oder mehr ganzen Zahlen.

Der größte gemeinsame Teiler ist die größte positive ganze Zahl, die durch die sich jede der angegebenen ganzen Zahlen ohne einen Rest teilen lassen.

### Syntax

GGT(Ganzzahl_1; Ganzzahl_2; ...; Ganzzahl_30)

Ganzzahl_1 bis 30 sind bis zu 30 ganze Zahlen, deren größter gemeinsamer Teiler berechnet werden soll.

### Beispiel

=GGT(16;32;24) ergibt 8, weil 8 die größte Zahl ist, durch die 16, 24 und 32 ohne Rest geteilt werden können.

=GGT(B1:B3) ergibt 3, wenn die Zellen B1, B2 und B3 die Werte 9, 12 und 9 enthalten.

## GGT_EXCEL2003

Das Ergebnis ist der größte gemeinsame Teiler einer Liste von Zahlen.

Die Funktionen, deren Namen mit _ADD oder _EXCEL2003 enden, geben dieselben Ergebnisse zurück wie die entsprechenden Funktionen in Microsoft Excel ohne Endung. Verwenden Sie die Funktionen ohne Endung, um Ergebnisse zu erhalten, die auf internationalen Standards basieren.

### Syntax

GGT_EXCEL2003(Zahl(en))

Zahl(en) ist eine Liste von bis zu 30 Zahlen.

### Beispiel

=GGT_EXCEL2003(5;15;25) ergibt 5.

## GRAD

Rechnet Bogenmaß in Grad um.

### Syntax

GRAD(Zahl)

Zahl ist der Winkel im Bogenmaß, der in Grad umgewandelt werden soll.

### Beispiel

=GRAD(PI()) ergibt 180 Grad.

## ISO.OBERGRENZE

Rundet eine Zahl auf das nächste Vielfache der Schrittweite auf, ungeachtet des Vorzeichens der Schrittweite.

### Syntax

ISO.OBERGRENZE(Zahl; Schrittweite)

Zahl (erforderlich) ist die Zahl, die aufgerundet werden soll.

Schrittweite (optional) ist die Zahl, auf deren Vielfaches der Wert aufgerundet werden soll.

### Beispiel

=ISO.OBERGRENZE(-11;-2) ergibt -10

## KGV

Ergibt das kleinste gemeinsame Vielfache von zwei oder mehr ganzen Zahlen.

### Syntax

KGV(Ganzzahl 1; Ganzzahl 2; ...; Ganzzahl 30)

Ganzzahl 1 bis 30 sind bis zu 30 ganze Zahlen, deren kleinstes gemeinsames Vielfaches berechnet werden soll.

### Beispiel

Wenn Sie die Zahlen 512, 1024 und 2000 in die Textfelder "Ganzzahl 1, 2 und 3 eingeben, wird 128000 als Ergebnis zurückgegeben.

## KGV_EXCEL2003

Das Ergebnis ist das kleinste gemeinsame Vielfache einer Liste von Zahlen.

Die Funktionen, deren Namen mit _ADD oder _EXCEL2003 enden, geben dieselben Ergebnisse zurück wie die entsprechenden Funktionen in Microsoft Excel ohne Endung. Verwenden Sie die Funktionen ohne Endung, um Ergebnisse zu erhalten, die auf internationalen Standards basieren.

### Syntax

KGV_EXCEL2003(Zahl(en))

Zahl(en) ist eine Liste von bis zu 30 Zahlen.

### Beispiel

=KGV_EXCEL2003(5;15;25) ergibt 75.

## KOMBINATIONEN

Ergibt die Anzahl von Kombinationen für Elemente ohne Wiederholung.

### Syntax

KOMBINATIONEN(Anzahl_1; Anzahl_2)

Anzahl_1 ist die Anzahl von Elementen in der Gruppe.

Anzahl_2 ist die Anzahl von Elementen, die aus der Gruppe ausgewählt werden.

KOMBINATIONEN ergibt die Anzahl geordneten Wege zur Auswahl dieser Elemente. Wenn beispielsweise 3 Elemente A, B und C in einer Gruppe zusammengefasst sind, haben Sie 3 verschiedene Möglichkeiten, um 2 Elemente auszuwählen, nämlich AB, AC und BC.

KOMBINATIONEN führt folgende Formel aus: Anzahl_1!/(Anzahl_2!*(Anzahl_1-Anzahl_2)!)

### Beispiel

=KOMBINATIONEN(3;2) ergibt 3.

## KOMBINATIONEN2

Ergibt die Anzahl von Kombinationen einer Teilmenge von Elementen einschließlich Wiederholung.

### Syntax

KOMBINATIONEN2(Anzahl_1; Anzahl_2)

Anzahl_1 ist die Anzahl von Elementen in der Gruppe.

Anzahl_2 ist die Anzahl von Elementen, die aus der Gruppe ausgewählt werden.

KOMBINATIONEN2 ergibt die Anzahl von eindeutigen Wegen zur Auswahl dieser Elemente, wobei die Reihenfolge der Auswahl irrelevant ist. Wenn beispielsweise 3 Elemente A,B und C in einer Gruppe zusammengefasst sind, haben Sie 6 Möglichkeiten, um 2 Elemente auszuwählen, nämlich AA, AB, AC, BB, BC und CC.

KOMBINATIONEN2 führt folgende Formel aus: (Anzahl_1+Anzahl_2-1)! / (Anzahl_2!*(Anzahl_1-1)!)

### Beispiel

=KOMBINATIONEN(3;2) ergibt 6.

## KÜRZEN

Kürzt eine Zahl durch das Entfernen von Dezimalstellen.

### Syntax

KÜRZEN(Zahl; Anzahl)

Ergibt Zahl, mit den möglichen durch Anzahl definierten Dezimalstellen. Überschüssige Dezimalstellen werden einfach entfernt, ungeachtet des Vorzeichens.

KÜRZEN(Zahl; 0) verhält sich wie GANZZAHL(Zahl) bei positiven Zahlen, bei negativen Zahlen wird jedoch in Richtung Null gerundet.

Die sichtbaren Dezimalstellen eines Ergebnisses können Sie unter LibreOffice - Eigenschaften Extras - Optionen... - LibreOffice Calc - Berechnen einstellen.

### Beispiel

=KÜRZEN(1,239;2) ergibt 1,23. Die 9 geht verloren.

=KÜRZEN(-1,234999;3) ergibt -1,234. Alle Neunen gehen verloren.

## LN

Ergibt den natürlichen Logarithmus einer Zahl, basierend auf der Konstante e. Die Konstante e hat etwa Wert 2,71828182845904.

### Syntax

LN(Zahl)

Zahl ist der Wert, dessen natürlicher Logarithmus berechnet werden soll.

### Beispiel

=LN(3) ergibt den natürlichen Logarithmus von 3 (etwa 1,0986).

=LN(EXP(321)) ergibt 321.

## LOG

Ergibt den Logarithmus zu der angegebenen Basis.

### Syntax

LOG(Zahl; Basis)

Zahl ist der Wert, dessen Logarithmus berechnet werden soll.

Basis (optional) ist die Basis des zu berechnenden Logarithmus. Wenn dieser Parameter fehlt, wird als Basis 10 genommen.

### Beispiel

=LOG(10;3) ergibt den Logarithmus von 10 zur Basis 3 (etwa 2,0959).

=LOG(7^4;7) ergibt 4.

## LOG10

Ergibt den Logarithmus einer Zahl zur Basis 10.

### Syntax

LOG10(Zahl)

Ergibt den Logarithmus von Zahl zur Basis 10.

### Beispiel

=LOG10(5) ergibt den Logarithmus von 5 zur Basis 10 (etwa 0,69897).

## OBERGRENZE

Rundet eine Zahl auf das nächste Vielfache der Schrittweite auf.

### Syntax

OBERGRENZE(Zahl; Schrittweite; Modus)

Zahl ist die Zahl, die aufgerundet werden soll.

Schrittweite ist die Zahl, auf deren Vielfaches der Wert aufgerundet werden soll.

Modus ist ein optionaler Wert. Wenn der Wert für Modus angegeben und ungleich Null ist und wenn Zahl und Schrittweite negativ sind, dann erfolgt eine Rundung ausgehend vom absoluten Wert von Zahl, beispielsweise werden negative Zahlen von Null weg gerundet. Wenn der Wert für Modus gleich Null oder nicht angegeben ist, dann werden negative Zahlen zu Null hin gerundet.

Wenn die Tabelle nach MS Excel exportiert wird, wird die Funktion OBERGRENZE als ihre äquivalente Funktion OBERGRENZE.MATHEMATIK exportiert, welche seit Excel 2013 existiert. Wenn Sie die Verwendung der Tabelle mit einer älteren Excel-Version planen, verwenden Sie entweder OBERGRENZE.GENAU, welche seit Excel 2010 existiert, oder OBERGRENZE.EXCEL, welche OBERGRENZE als eine für alle Excel-Versionen kompatible Funktion exportiert. Beachten Sie, dass OBERGRENZE.EXCEL immer von Null wegrundet.

### Beispiel

=OBERGRENZE(-11;-2) ergibt -10

=OBERGRENZE(-11;-2;0) ergibt -10

=OBERGRENZE(-11;-2;1) ergibt -12

## OBERGRENZE.EXCEL

Rundet eine Zahl auf das nächste Vielfache der Schrittweite weg von Null.

Diese Funktion ist seit LibreOffice verfügbar5.0

### Syntax

OBERGRENZE.EXCEL(Zahl; Schrittweite)

Zahl ist die Zahl, die gerundet werden soll.

Schrittweite ist der Wert, auf dessen Vielfaches die Zahl gerundet wird.

Diese Funktion existiert für die Interoperabilität mit Microsoft Excel 2007 oder älteren Versionen.

### Beispiel

=OBERGRENZE.EXCEL(1;3) ergibt 3

=OBERGRENZE.EXCEL(7;4) ergibt 8

=OBERGRENZE.EXCEL(-10;-3) ergibt -12

## OBERGRENZE.GENAU

Rundet eine Zahl auf das nächste Vielfache der Schrittweite auf, ungeachtet des Vorzeichens der Schrittweite.

Diese Funktion ist seit LibreOffice verfügbar4.3

### Syntax

OBERGRENZE.GENAU(Zahl; Schrittweite)

Zahl (erforderlich) ist die Zahl, die aufgerundet werden soll.

Schrittweite (optional) ist die Zahl, auf deren Vielfaches der Wert aufgerundet werden soll.

### Beispiel

=OBERGRENZE.GENAU(-11;-2) ergibt -10

## OBERGRENZE.MATHEMATIK

Rundet eine Zahl auf das nächste Vielfache der Schrittweite auf.

### Syntax

OBERGRENZE.MATHEMATIK(Zahl; Schrittweite; Modus)

Zahl ist die Zahl, die aufgerundet werden soll.

Schrittweite ist die Zahl, auf deren Vielfaches der Wert aufgerundet werden soll.

Modus ist ein optionaler Wert. Wenn der Wert für Modus angegeben und ungleich Null ist und wenn Zahl und Schrittweite negativ sind, dann erfolgt eine Rundung ausgehend vom absoluten Wert von Zahl, beispielsweise werden negative Zahlen von Null weg gerundet. Wenn der Wert für Modus gleich Null oder nicht angegeben ist, dann werden negative Zahlen zu Null hin gerundet.

Diese Funktion existiert für die Interoperabilität mit Microsoft Excel 2013 oder neuer.

### Beispiel

=OBERGRENZE.MATHEMATIK(-10;-3) ergibt -9

=OBERGRENZE.MATHEMATIK(-10;-3;0) ergibt -9

=OBERGRENZE.MATHEMATIK(-10;-3;1) ergibt -12

## PI

Ergibt 3,14159265358979, der Wert der mathematischen Konstanten Pi auf 14 Dezimalstellen.

### Syntax

PI()

### Beispiel

=PI() ergibt 3,14159265358979.

## POLYNOMIAL

Ergibt die Fakultät der Summe der Argumente geteilt durch das Produkt der Fakultäten der Argumente.

### Syntax

POLYNOMIAL(Zahl(en))

Zahl(en) ist eine Liste von bis zu 30 Zahlen.

### Beispiel

=POLYNOMIAL(F11:H11) ergibt 1260, wenn in F11 bis H11 die Werte 2, 3 und 4 enthalten sind. Dies entspricht der Formel =(2+3+4)! / (2!*3!*4!)

## POTENZ

Ergibt eine Zahl hoch eine andere Zahl.

### Syntax

POTENZ(Basis; Exponent)

Ergibt Basis hoch Exponent.

Das gleiche Resultat wird erzielt, wenn man den Exponentialoperator ^ verwendet:

Basis^Exponent

### Beispiel

=POTENZ(4;3) ergibt 64, also 4 hoch 3.

=4^3 ergibt auch 64, das Ergebnis von 4 hoch 3.

## POTENZREIHE

Summiert die ersten Glieder einer Potenzreihe.

POTENZREIHE(X;N;M;Koeffizient(en))=Koeffizient_1*X^N+Koeffizient_2*X^(N+M)+Koeffizient_3*X^(N+2M)+...+Koeffizient_i*X^(N+(i-1)M)

### Syntax

POTENZREIHE(X; N; M; Koeffizient(en))

X ist der Basiswert für die Potenzenreihe.

N ist der Anfangsexponent

M ist die Schrittweite der Erhöhung von N

Koeffizient(en) ist eine Folge von Koeffizienten. Für jeden Koeffizienten wird die Reihen um einen Summanden erweitert.

## PRODUKT

Multipliziert alle gegebenen Zahlen als Argumente und ergibt das Produkt.

### Syntax

PRODUKT(Zahl_1; Zahl_2; ...; Zahl_30)

Zahl_1 bis 30 sind bis zu 30 Argumente, deren Produkt berechnet werden soll.

PRODUKT ergibt Zahl 1 * Zahl 2 * Zahl_3 * ...

### Beispiel

=PRODUKT(2;3;4) ergibt 24.

## QUADRATESUMME

Um die Quadratsumme von Zahlen zu berechnen (Summe der Quadrate von Argumenten), so geben Sie diese als Argumente ein.

### Syntax

QUADRATESUMME(Zahl_1; Zahl_2; ...; Zahl_30)

Zahl_1 bis 30 sind bis zu 30 Argumente, deren Quadratsumme berechnet werden soll.

### Beispiel

Wenn Sie die Zahlen 2, 3 und 4 als Argumente für Zahl_1, 2 und 3 eingeben, wird 29 als Ergebnis zurückgegeben.

## QUOTIENT

Ergibt den ganzzahligen Teil einer Division.

### Syntax

QUOTIENT(Dividend; Divisor)

Ergibt den ganzzahligen Teil der Division von Dividend durch Divisor.

QUOTIENT ist gleichwertig mit GANZZAHL(Zähler/Nenner) für Zähler und Nenner mit gleichem Vorzeichen, bis auf dass unterschiedliche Fehlercodes zurückgegeben werden. Allgemeiner ist es gleichwertig mit GANZZAHL(Zähler/Nenner/VORZEICHEN(Zähler/Nenner))*VORZEICHEN(Zähler/Nenner).

### Beispiel

=QUOTIENT(11;3) ergibt 3. Der Rest 2 geht verloren.

## REST

Ergibt den Rest bei der Division einer ganzen Zahl durch eine andere.

### Syntax

REST(Divident; Divisor)

Bei ganzzahligen Argumenten ergibt diese Funktion Dividend Modulo Divisor, das heißt den Rest, wenn der Dividend durch Divisor geteilt wird.

Diese Funktion wird als Dividend-Divisor*GANZZAHL(Dividend/Divisor) ausgeführt und berechnet auch ein Ergebnis, wenn die Argumente keine Ganzzahlen sind.

### Beispiel

=REST(22;3) ergibt 1, den Rest der Division von 22 durch 3.

=REST(11,25;2,5) ergibt 1,25.

## RUNDEN

Rundet eine Zahl auf eine festgelegte Anzahl von Nachkommastellen.

### Syntax

RUNDEN(Zahl; Stellen)

Ergibt Zahl, gerundet auf die durch Stellen definierten Dezimalstellen. Wenn Stellen weggelassen wird oder null ist, rundet die Funktion auf die nächste Ganzzahl. Wenn Stellen negativ ist, rundet die Funktion auf die nächsten 10, 100, 1000 und so weiter.

Diese Funktion rundet auf die nächstgelegene Zahl. Für Alternativen siehe ABRUNDEN und AUFRUNDEN.

### Beispiel

=RUNDEN(2,348;2) ergibt 2,35

=RUNDEN(-32,4834;3) ergibt -32,483. Ändern Sie das Zellenformat, um alle Dezimalstellen anzuzeigen.

=RUNDEN(2,348;0) ergibt 2.

=RUNDEN(2,5) ergibt 3.

=RUNDEN(987,65;-2) ergibt 1000.

## SEC

Ergibt den Sekans des vorgegebenen Winkels (im Bogenmaß). Der Sekans eines Winkels entspricht 1 geteilt durch den Kosinus des Winkels.

Diese Funktion ist seit LibreOffice verfügbar3.5

### Syntax

SEC(Zahl)

Ergibt den Sekans von Zahl, den Winkel im Bogenmaß.

Um den Sekans eines in Grad angegebenen Winkels zu berechnen, verwenden Sie die Funktion BOGENMASS.

### Beispiel

=SEC(PI()/4) ergibt näherungsweise 1,4142135624, den Arkuskosinus von Pi/4 Bogenmaß.

=SEC(BOGENMASS(60)) ergibt 2, den Sekans von 60 Grad.

## SECHYP

Ergibt den Sekans Hyperbolicus einer Zahl.

Diese Funktion ist seit LibreOffice verfügbar3.5

### Syntax

SECHYP(Zahl)

Ergibt den Sekans Hyperbolicus von Zahl.

### Beispiel

=SECHYP(0) ergibt 1, den Sekans Hyperbolicus von 0.

## SIN

Ergibt den Sinus eines gegebenen Winkels (im Bogenmaß).

### Syntax

SIN(Zahl)

Ergibt den (trigonometrischen) Sinus von Zahl, den Winkel im Bogenmaß.

Um den Sinus eines in Grad angegebenen Winkels zu berechnen, verwenden Sie die Funktion BOGENMASS.

### Beispiel

=SIN(PI()/2) ergibt 1, den Sinus von Pi/2 Bogenmaß.

=SIN(BOGENMASS(30)) ergibt 0,5, den Sinus von 30 Grad.

## SINHYP

Ergibt den Sinus Hyperbolicus einer Zahl.

### Syntax

SINHYP(Zahl)

Ergibt den Sinus Hyperbolicus von Zahl.

### Beispiel

=SINHYP(0) ergibt 0, den Sinus Hyperbolicus von 0.

## SUMME

Summiert alle Zahlen eines Zellbereichs.

### Syntax

SUMME(Zahl_1; Zahl_2; ...; Zahl_30)

Zahl_1 bis Zahl_30 sind bis zu 30 Argumente, deren Summe berechnet werden soll.

### Beispiel

Wenn Sie die Zahlen 2, 3 und 4 in die für Zahl_1, 2 und 3 eingeben, wird 6 als Ergebnis zurückgegeben.

=SUMME(A1;A3;B5) berechnet die Summe der Werte der angegebenen drei Zellen. =SUMME (A1:E10) berechnet die Summe der Werte aller Zellen im rechteckigen Bereich A1 bis E10.

In der Funktion SUMME() können UND-Verknüpfungen wie folgt eingesetzt werden:

Beispiel: Angenommen, Sie haben Rechnungen in eine Tabelle eingegeben. Spalte A enthält das Datum der jeweiligen Rechnung, Spalte B die jeweiligen Beträge. Sie möchten eine Formel verwenden, mit der Sie die Summe aller Beträge für einen bestimmten Monat berechnen können, beispielsweise den Betrag für den Zeitraum >=01.01.2008 bis <01.02.2008. Die Daten umfassen den Bereich A1:A40, die zusammenzurechnenden Beträge umfassen den Bereich B1:B40. C1 enthält das Anfangsdatum 01.01.2008 der einzubeziehenden Rechnungen und C2 enthält das Datum 01.02.2008, das nicht mehr einbezogen wird.

Geben Sie die folgende Formel als Matrixformel ein:

=SUMME((A1:A40>=C1)*(A1:A40<C2)*B1:B40)

Um diese Formel als eine Matrixformel einzugeben, schließen Sie sie nicht einfach durch Drücken der Eingabetaste ab, sondern beenden den Befehl mit Umschalt+Befehl Strg+Eingabetaste. Die Formel in der Rechenleiste wird daraufhin in geschweifte Klammern gesetzt.

{=SUMME((A1:A40>=C1)*(A1:A40<C2)*B1:B40)}

Die Formel basiert auf der Tatsache, dass das Ergebnis eines Vergleichs 1 ist, wenn das Kriterium erfüllt ist, und 0, wenn das Kriterium nicht erfüllt ist. Die einzelnen Vergleichsergebnisse werden als Matrix behandelt und in der Matrixmultiplikation verwendet, abschließend werden die einzelnen Werte zusammengerechnet, woraus sich die Ergebnismatrix ergibt.

## SUMMEWENN

Diese Funktion addiert nur jene Zellen, die eine vorgegebene Bedingung erfüllen. Diese Funktion können Sie auch verwenden, um einen Bereich nach einem bestimmten Wert zu durchsuchen.

Die Suche unterstützt auch reguläre Ausdrücke. Sie können zum Beispiel "all.*" eingeben, um die erste Stelle von "all", gefolgt von irgendeinem Zeichen, zu finden. Falls Sie nach Text suchen, der auch ein regulärer Ausdruck ist, müssen Sie jedem Zeichen ein \-Zeichen voranstellen. Sie können die automatische Auswertung regulärer Ausdrücke in LibreOffice - Einstellungen Extras - Optionen... - LibreOffice Calc - Berechnen ein- und ausschalten.

### Syntax

SUMMEWENN(Bereich; Kriterien; Summenbereich)

Bereich ist der Bereich, auf den die Kriterien angewendet werden sollen.

Kriterien ist die Zelle, in der das Suchkriterium angegeben ist, oder das Suchkriterium selbst. Das Kriterium wird in die Formel eingefügt und muss in doppelten Anführungszeichen stehen.

Summenbereich ist der Bereich, aus dem die Werte summiert werden sollen. Wenn dieser Parameter nicht angegeben ist, werden die in Bereich gefundenen Werte summiert.

SUMMEWENN unterstützt den Bezugsverkettungsoperator (~) nur im Parameter Kriterien und dies auch nur, wenn der optionale Parameter Summenbereich nicht angegeben ist.

### Beispiel

Summieren ausschließlich negativer Zahlen im Bereich A1:A10: =SUMMEWENN(A1:A10;"<0")

=SUMMEWENN(A1:A10;">0";B1:10) summiert nur Werte aus dem Bereich B1:B10, wenn die entsprechenden Werte im Bereich A1:A10 größer als 0 sind.

Weitere Syntaxbeispiele für die Funktion SUMMEWENN() finden Sie bei der Funktion ZÄHLENWENN().

## TAN

Ergibt den Tangens des gegebenen Winkels (im Bogenmaß).

### Syntax

TAN(Zahl)

Ergibt den (trigonometrischen) Tangens von Zahl, den Winkel im Bogenmaß.

Um den Tangens eines in Grad angegebenen Winkels zu berechnen, verwenden Sie die Funktion BOGENMASS.

### Beispiel

=TAN(PI()/4) ergibt 1, den Tangens von Pi/4 Bogenmaß.

=TAN(BOGENMASS(45)) ergibt 1, den Tangens von 45 Grad.

## TANHYP

Ergibt den Tangens Hyperbolicus einer Zahl.

### Syntax

TANHYP(Zahl)

Ergibt den Tangens Hyperbolicus von Zahl.

### Beispiel

=TANHYP(0) ergibt 0, den Tangens Hyperbolicus von 0.

## TEILERGEBNIS

Berechnet Teilergebnisse. Sollte ein Bereich bereits Teilergebnisse enthalten, werden diese nicht in die weitere Berechnung einbezogen. Verwenden Sie diese Funktion gemeinsam mit AutoFiltern, damit nur die gefilterten Datensätze berücksichtigt werden.

### Syntax

TEILERGEBNIS(Funktion; Bereich)

Funktion ist eine Zahl, die für eine der folgenden Funktionen steht:

Funktionsindex (einschließlich versteckter Werte) | Funktionsindex (versteckte Werte werden ignoriert) | Funktion
1 | 101 | MITTELWERT
2 | 102 | ANZAHL
3 | 103 | ANZAHL2
4 | 104 | MAX
5 | 105 | MIN
6 | 106 | PRODUKT
7 | 107 | STABW
8 | 108 | STABWN
9 | 109 | SUMME
10 | 110 | VARIANZ
11 | 111 | VARIANZEN

Verwenden Sie die Zahlen 1-11, um manuell ausgeblendete Zeilen zu berücksichtigen, oder 101-111, um sie nicht zu berücksichtigen; herausgefilterte Zellen werden nie berücksichtigt.

Bereich ist der Bereich, dessen Zellen berücksichtigt werden.

### Beispiel

Sie haben eine Tabelle im Zellbereich A1:B6 mit einer Stückliste für 10 Schüler. Zeile 2 (Füller) ist manuell ausgeblendet. Sie möchten die Summe der angezeigten Stückzahlen sehen; das heißt die Zwischensumme der eingeblendeten Zeilen. In diesem Fall ist die Formel:

| A | B
1 | ARTIKEL | ANZAHL
2 | Füller | 10
3 | Stift | 10
4 | Notizbuch | 10
5 | Radiergummi | 10
6 | Anspitzer | 10

=TEILERGEBNIS(9;B2:B6) ergibt 50.

=TEILERGEBNIS(109;B2:B6) ergibt 40.

## UMRECHNEN_OOO

Rechnet den Wert von einer Maßeinheit in eine andere Maßeinheit um. Die Umrechnungsfaktoren sind in einer Konfigurationsliste abgelegt.

Die Umrechnungsliste enthielt früher die europäischen Währungen und den Euro (siehe Beispiele). Wir empfehlen aber, die neue Funktion EUROUMRECHNEN zu verwenden, um diese Währungen umzurechnen.

### Syntax

UMRECHNEN_OOO(Wert;"Text";"Text")

### Beispiel

=UMRECHNEN_OOO(100;"ATS";"EUR") ergibt den Wert von 100 Österreichischen Schilling in Euro.

=UMRECHNEN_OOO(100;"EUR";"DEM") rechnet 100 Euro in Deutsche Mark um.

## UNGERADE

Rundet eine positive Zahl auf die nächste ungerade ganze Zahl auf und eine negative Zahl auf die nächste ungerade ganze Zahl ab.

### Syntax

UNGERADE(Zahl)

Ergibt Zahl gerundet auf die nächste ungerade ganze Zahl, weg von Null.

### Beispiel

=UNGERADE(1,2) ergibt 3.

=UNGERADE(1) ergibt 1.

=UNGERADE(0) ergibt 1.

=UNGERADE(-3,1) ergibt -5.

## UNTERGRENZE

Rundet eine Zahl auf das nächste Vielfache der Schrittweite ab.

### Syntax

UNTERGRENZE(Zahl; Schrittweite; Modus)

Zahl ist die Zahl, die abgerundet werden soll.

Schrittweite ist der Wert, auf dessen Vielfaches die Zahl abgerundet wird.

Modus ist ein optionaler Wert. Wenn der Wert für Modus angegeben und ungleich Null ist und wenn Zahl und Schrittweite negativ sind, dann erfolgt eine Rundung ausgehend vom absoluten Wert von Zahl, beispielsweise werden negative Zahlen zu Null hin gerundet. Wenn der Wert für Modus gleich Null oder nicht angegeben ist, dann werden negative Zahlen von Null weg gerundet.

Wenn die Tabelle nach Microsoft Excel exportiert wird, wird die Funktion UNTERGRENZE als ihre äquivalente Funktion UNTERGRENZE.MATHEMATIK exportiert, welche seit Excel 2013 existiert. Wenn Sie die Verwendung der Tabelle mit einer älteren Excel-Version planen, verwenden Sie entweder UNTERGRENZE.GENAU, welche seit Excel 2010 existiert, oder UNTERGRENZE.EXCEL, welche UNTERGRENZE als eine für alle Excel-Versionen kompatible Funktion exportiert. Beachten Sie, dass UNTERGRENZE.EXCEL immer hin zu Null rundet.

### Beispiel

=UNTERGRENZE( -11;-2) ergibt -12

=UNTERGRENZE( -11;-2;0) ergibt -12

=UNTERGRENZE( -11;-2;1) ergibt -10

## UNTERGRENZE.GENAU

Rundet eine Zahl auf das nächste Vielfache der Schrittweite ab, unabhängig vom Vorzeichen der Schrittweite.

Diese Funktion ist seit LibreOffice verfügbar4.3

### Syntax

UNTERGRENZE.GENAU(Zahl; Schrittweite)

Zahl ist die Zahl, die abgerundet werden soll.

Schrittweite ist der Wert, auf dessen Vielfaches die Zahl abgerundet wird.

### Beispiel

=UNTERGRENZE.GENAU(-11;-2) ergibt -12

## VORZEICHEN

Ergibt das Vorzeichen einer Zahl. Ergibt 1, wenn die Zahl positiv ist, -1 wenn sie negativ ist, und 0, wenn sie Null ist.

### Syntax

VORZEICHEN(Zahl)

Zahl ist die Zahl, deren Vorzeichen bestimmt werden soll.

### Beispiel

=VORZEICHEN(3,4) ergibt 1.

=VORZEICHEN(-4,5) ergibt -1.

## VRUNDEN

Ergibt eine Zahl auf das nächste ganzzahlige Vielfache einer anderen Zahl gerundet.

### Syntax

VRUNDEN(Zahl; Vielfaches)

Ergibt Zahl auf das nächste Vielfache von Vielfaches gerundet.

Eine alternative Umsetzung ist Vielfaches*RUNDEN(Zahl/Vielfaches).

### Beispiel

=VRUNDEN(15,5;3) ergibt 15, da 15,5 dichter an 15 (=3*5) liegt als an 18 (=3*6).

=VRUNDEN(1,4;0,5) ergibt 1,5 (=0,5*3).

## WURZEL

Ergibt die positive Quadratwurzel einer Zahl.

### Syntax

WURZEL(Zahl)

Ergibt die positive Quadratwurzel von Zahl.

Zahl muss positiv sein.

### Beispiel

=WURZEL(16) ergibt 4.

=WURZEL(-16) ergibt den Fehler Ungültiges Argument.

## WURZELPI

Ergibt Quadratwurzel aus (Pi mal Zahl).

### Syntax

WURZELPI(Zahl)

Ergibt die positive Quadratwurzel aus (PI mal Zahl).

Dies entspricht WURZEL(PI()*Zahl).

### Beispiel

=WURZELPI(2) ergibt die Quadratwurzel von (2*Pi), etwa 2,506628.

## ZUFALLSBEREICH

Ergibt eine ganze Zufallszahl aus einem festgelegten Bereich.

### Syntax

ZUFALLSBEREICH(Kleinste_Zahl; Größte_Zahl)

Ergibt eine ganze Zufallszahl zwischen den ganzen Zahlen Kleinste_Zahl und Größte_Zahl (einschließlich beider).

Diese Funktion erzeugt jedes Mal, wenn Calc neu berechnet, eine neue Zufallszahl. Um die Neuberechnung in Calc zu erzwingen, drücken Sie die Taste F9.

Um Zufallszahlen zu generieren, die nicht wieder neu berechnet werden, kopieren Sie die Zellen, in denen diese Funktion enthalten ist, und verwenden Bearbeiten - Inhalte einfügen... (wobei im sich öffnenden Dialog Alles einfügen und Formeln nicht aktiviert sein darf und Zahlen aktiviert sein muss).

### Beispiel

=ZUFALLSBEREICH(20;30) ergibt eine ganze Zahl zwischen 20 und 30.

## ZUFALLSZAHL

Ergibt eine Zufallszahl zwischen 0 bis 1.

### Syntax

ZUFALLSZAHL()

Diese Funktion erzeugt jedes Mal, wenn Calc neu berechnet, eine neue Zufallszahl. Um die Neuberechnung in Calc zu erzwingen, drücken Sie die Taste F9.

Um Zufallszahlen zu generieren, die nicht neu berechnet werden sollen, kopieren Sie Zellen, in denen =ZUFALLSZAHL() enthalten ist, und verwenden Bearbeiten - Inhalte einfügen... (wobei im sich öffnenden Dialog Alles einfügen und Formeln nicht aktiviert sein darf und Zahlen aktiviert sein muss).

### Beispiel

=ZUFALLSZAHL() ergibt eine Zufallszahl zwischen 0 und 1.

Verwandte Themen

Funktionen nach Kategorie