Inhalte
Index 🔎︎

# Funktionen für Tabellen

Dieser Abschnitt enthält Beschreibungen der Funktionen aus der Kategorie Tabelle und Beispiele zur Veranschaulichung.

So greifen Sie auf diesen Befehl zu:

Einfügen - Funktion - Kategorie Tabellendokument

## FEHLER.TYP

Ergibt eine Zahl, die dem Fehlertyp entspricht, oder den Fehlerwert #NV, wenn kein Fehler vorliegt.

## ADRESSE

Ergibt für die angegebene Zeilen- und Spaltennummer eine Zelladresse (Bezug auf die Zelle) in Textform. Sie können auch bestimmen, ob die Adresse als absolute (beispielsweise $A$1) oder relative Adresse (beispielsweise A1) oder als Mischform (beispielsweise A$1 oder $A1) interpretiert wird. Außerdem können Sie den Namen der Tabelle angeben.

Für die Kompatibilität besitzen die Funktionen ADRESSE und INDIREKT nun einen optionalen Parameter, der angibt, ob die R1C1-Schreibweise anstatt der üblichen A1-Schreibweise verwendet werden soll.

In ADRESSE ist dieser Parameter als 4. Parameter eingefügt worden. Der optionale Tabellenname ist nun an die 5. Stelle gerutscht.

Bei INDIREKT wird dieser Parameter als 2. Parameter angehängt.

Bei beiden Funktionen gilt, wenn das Argument mit dem Wert 0 eingefügt wird, dann wird die R1C1-Schreibweise verwendet. Wenn das Argument nicht angegeben wird oder einen Wert ungleich 0 hat, dann wird die A1-Schreibweise verwendet.

Im Falle der R1C1-Schreibweise ergibt ADRESSE das Ausrufezeichen '!' als Trennzeichen für den Tabellennamen und INDIREKT erwartet das Ausrufezeichen als Trennzeichen für Tabellennamen. Beide Funktionen verwenden den Punkt '.' als Trennzeichen im Falle der A1-Schreibweise.

Wenn ein Dokument im Format ODF 1.0/1.1 geöffnet wird und die Funktion ADRESSE einen 4. Parameter als Tabellennamen besitzt, wird dieser an die Stelle des 5. Parameters verschoben. Ein neuer 4. Parameter mit dem Wert 1 wird eingefügt.

Wenn ein Dokument im Format ODF 1.0/1.1 gespeichert wird und für die Funktion ADRESSE ein 4. Parameter festgelegt ist, wird dieser entfernt.

Speichern Sie kein Tabellendokument im alten Format ODF 1.0/1.1, wenn der neue 4. Parameter der Funktion ADRESSE mit dem Wert 0 verwendet wird.

Die Funktion INDIREKT wird ohne Umwandlung im Format ODF 1.0/1.1 gespeichert. Wenn der 2. Parameter vorhanden ist, liefert eine ältere Version von Calc somit einen Fehler für diese Funktion.

### Syntax

ADRESSE(Zeile; Spalte; Bezug; A1; "Tabelle")

Zeile stellt die Zeilennummer für den Zellbezug dar

Spalte stellt die Spaltennummer für den Zellbezug dar (als Zahl, nicht den Buchstaben)

Bezug (optional) bestimmt die Art des Bezuges:

1 oder leer: Absolut ($A$1)

2: Zeile absolut; Spalte relativ (A$1)

3: Zeile relativ; Spalte absolut ($A1)

4: Relativ (A1)

Wenn A1 (optional) auf 0 gesetzt ist, wird die R1C1-Schreibweise verwendet. Wenn dieser Parameter fehlt oder einen anderen Wert als 0 hat, wird die A1-Schreibweise verwendet.

Tabelle (optional) gibt den Namen der Tabelle an. Er muss in doppelten Anführungszeichen stehen.

### Beispiel:

=ADRESSE(1;1;2;;"Tabelle2") ergibt Folgendes: Tabelle2.A$1

Wenn die Formel oberhalb in Zelle B2 der aktuellen Tabelle steht und die Zelle A1 in Tabelle2 den Wert -6 enthält, können Sie indirekt auf die referenzierte Zelle verweisen, indem Sie in B1 der Tabelle1 =ABS(INDIREKT(A1)) eingeben. Das Ergebnis ist der Betrag (absolute Wert) des in A1 angegebenen Zellbezugs, in diesem Falle 6.

## BEREICHE

Ergibt die Anzahl der Einzelbereiche eines Mehrfachbereichs. Ein Bereich kann entweder aus aufeinander folgenden Zellen oder einer einzelnen Zelle bestehen.

Diese Funktion erwartet ein einziges Argument. Um mehrere Bereiche anzugeben, müssen Sie diese in zusätzlichen Klammern einschließen. Mehrfachbereiche können mithilfe des Semikolons (;) als Trennzeichen eingegeben werden, wobei dies automatisch in die Tilde (~) umgewandelt wird. Die Tilde ist der Verkettungsoperator für Bereiche.

### Syntax

BEREICHE(Bezug)

Bezug ist der Verweis auf eine Zelle oder einen Zellbereich.

### Beispiel

=BEREICHE((A1:B3;F2;G1)) ergibt 3, da es sich um einen Bezug auf drei separate Zellen und/oder Bereiche handelt. Nach der Eingabe wird dies in =BEREICHE((A1:B3~F2~G1)) umgewandelt.

=BEREICHE(Alles) ergibt 1, wenn Sie einen Bereich mit der Bezeichnung „Alles“ unter Daten - Bereich festlegen... festgelegt haben.

## DDE

Ergibt das Ergebnis einer DDE-Verknüpfung. Wenn sich der Inhalt des verknüpften Bereichs oder Abschnitts ändert, ändert sich auch der Rückgabewert. Um die aktualisierten Verknüpfungen anzuzeigen, müssen Sie entweder das Tabellendokument neu laden oder Bearbeiten - Verknüpfungen... wählen. Plattformübergreifende Verknüpfungen, wie beispielsweise von einer LibreOffice-Installation auf einem Windows-System zu einem auf einem Linux-System erstellten Dokument, sind nicht zulässig.

### Syntax

DDE("Server"; "Datei"; "Bereich"; Modus)

Server ist der Name einer Serveranwendung. Die LibreOffice-Anwendungen haben den Servernamen "soffice".

Datei ist der Name der Datei mit vollständigem Pfad.

Bereich ist ein Bereich, aus dem Daten gelesen werden sollen.

Modus ist ein optionaler Parameter, der steuert, wie die Daten vom DDE-Server in Zahlen umgewandelt werden.

Modus | Wirkung
0 oder fehlend | Zahlenformat aus der Zellvorlage "Standard"
1 | Daten werden immer mit Standardformat für US Englisch interpretiert
2 | Daten werden als Text übernommen, keine Wandlung in Zahlen

### Beispiel

=DDE("soffice";"c:\Office\Dokument\Daten1.ods";"Tabelle1.A1") liest den Inhalt der Zelle A1 in Tabelle1 des LibreOffice Calc-Tabellendokuments Daten1.ods.

=DDE("soffice";"c:\Office\Dokument\Motto.odt";"Heutiges Motto") gibt ein Motto in der Zelle zurück, in der diese Formel enthalten ist. Zunächst geben Sie eine Zeile im Dokument Motto.odt ein, in der das Motto enthalten ist. Dann definieren Sie die Zeile als erste Zeile eines Abschnitts mit der Bezeichnung Heutiges Motto (in LibreOffice Writer unter Einfügen - Bereich...). Wenn das Motto im LibreOffice Writer-Dokument geändert (und gespeichert) wird, wird es in allen Zellen in LibreOffice Calc aktualisiert, in denen diese DDE-Verknüpfung definiert ist.

## FEHLERTYP

Ergibt die Nummer eines in einer anderen Zelle aufgetretenen Fehlercodes. Sie können dann beispielsweise mithilfe dieser Nummer einen eigenen Fehlertext ausgeben lassen.

Bei einem Fehler gibt die Funktion einen Wahrheits- oder einen numerischen Wert zurück.

Wenn Sie auf die Zelle mit dem Fehler klicken, wird in der Statusleiste der in LibreOffice vordefinierte Fehlercode angezeigt.

### Syntax

FEHLERTYP(Bezug)

Bezug ist ein Bezug auf eine Zelle, in der ein Fehler gemeldet wird.

### Beispiel

Wenn die Zelle A1 Err:518 anzeigt, ergibt die Funktion =FEHLERTYP(A1) die Zahl 518.

## HYPERLINK

Wenn Sie auf eine Zelle klicken, die eine Funktion HYPERLINK enthält, wird der Hyperlink geöffnet.

Wenn Sie den optionalen Parameter Zelltext verwenden, sucht die Formel die URL und zeigt dann den Text oder die Zahl an.

Um eine Hyperlink-Zelle über die Tastatur zu öffnen, markieren Sie die Zelle, drücken F2, um in den Bearbeitungsmodus zu wechseln, stellen den Cursor vor den Hyperlink, drücken Umschalt+F10, und wählen dann Hyperlink öffnen.

### Syntax

HYPERLINK("URL") oder HYPERLINK("URL"; "Zelltext")

URL gibt das Verknüpfungsziel an. Der optionale Parameter Zelltext ist der in der Zelle angezeigte Text beziehungsweise eine Zahl und gleichzeitig das Ergebnis der Funktion. Wenn der Parameter Zelltext nicht angegeben ist, wird die URL im Zelltext und im Ergebnis der Funktion angezeigt.

Für leere Zellen und Matrixelemente wird die Zahl 0 zurückgegeben.

### Beispiel

=HYPERLINK("http://www.beispiel.org") zeigt in der Zelle den Text "http://www.beispiel.org" an und führt den Hyperlink http://www.beispiel.org aus, wenn auf diesen geklickt wird.

=HYPERLINK("http://www.beispiel.org";"Hier klicken") zeigt in der Zelle den Text "Hier klicken" an und führt den Hyperlink http://www.beispiel.org aus, wenn auf diesen geklickt wird.

=HYPERLINK("http://www.beispiel.org";12345) zeigt die Zahl 12345 an, und führt den Hyperlink http://www.beispiel.org aus, wenn auf diesen geklickt wird.

=HYPERLINK($B4), wobei Zelle B4 http://www.beispiel.org enthält. Die Funktion fügt http://www.beispiel.org zur URL der Hyperlinkzelle hinzu und ergibt den selben Text, der als Formelergebnis verwendet wird.

=HYPERLINK("http://www.";"Klicken Sie auf ") & "beispiel.org" zeigt in der Zelle den Text "Klicken Sie auf beispiel.org" an und führt den Hyperlink http://www.beispiel.org aus, wenn auf diesen geklickt wird.

=HYPERLINK("#Tabelle1.A1";"Gehe zum Anfang") zeigt den Text „Gehe zum Anfang“ an und springt zur Zelle Tabelle1.A1 des Dokuments.

=HYPERLINK("file:///C:/writer.odt#Spezifikation";"Gehe zu Writer-Lesenzeichen") zeigt den Text "Gehe zu Writer-Lesezeichen" an, lädt das angegebene Textdokument und springt zum Lesezeichen "Spezifikation".

## INDEX

INDEX ergibt einen Unterbereich, der durch eine Zeilen- und eine Spaltennummer definiert ist, oder einen optionalen Bereichsindex. Je nach Kontext ergibt INDEX einen Bezug oder Inhalt.

### Syntax

INDEX(Bezug; Zeile; Spalte; Bereich)

Bezug ist ein Bezug, der entweder direkt oder über einen Bereichsnamen eingegeben wird. Wenn der Bezug aus mehreren Bereichen besteht, müssen Sie den Bezug oder den Bereichsnamen in Klammern einschließen.

Zeile (optional) stellt den Zeilenindex des Bezugsbereichs dar, für den der Wert zurückgegeben wird. Im Falle von Null (keine bestimmte Zeile) werden alle referenzierten Zeilen zurückgegeben.

Spalte (optional) stellt den Spaltenindex des Bezugsbereichs dar, für den der Wert zurückgegeben wird. Im Falle von Null (keine bestimmte Spalte) werden alle referenzierten Spalten zurückgegeben.

Bereich (optional) stellt den Index des Unterbereichs dar, wenn der Bezug auf einen Mehrfachbereich verweist.

### Beispiel

=INDEX(Preise;4;1) ergibt den Wert aus Zeile 4 und Spalte 1 des Datenbankbereichs, der unter Daten - Bereich festlegen... als Preise festgelegt wurde.

=INDEX(SummeX;4;1) gibt den Wert aus dem Bereich SummeX in Zeile 4 und Spalte 1 zurück, wie unter Tabelle - Benannte Bereiche - Festlegen... definiert.

=INDEX(A1:B6;1) ergibt einen Bezug auf die erste Zeile von A1:B6.

=INDEX(A1:B6;0;1) ergibt einen Bezug auf die erste Spalte von A1:B6.

=INDEX((mehrfach);4;1) gibt den Wert an, der in Zeile 4 und Spalte 1 des (Mehrfach-) Bereichs enthalten ist, welchen Sie unter Tabelle - Benannte Bereiche - Festlegen... als mehrfach definiert haben. Der Mehrfachbereich kann aus verschiedenen rechteckigen Bereichen bestehen, jeder mit einer Zeile 4 und einer Spalte 1. Um nun den zweiten Block dieses Mehrfachbereichs aufzurufen, geben Sie die Nummer 2 als Parameter für Bereich ein.

=INDEX(A1:B6;1;1) gibt den Wert im oberen linken Teil des Bereichs A1:B6 an.

=INDEX((mehrfach);0;0;2) ergibt einen Bezug auf den zweiten Bereich des Mehrfachbereichs.

## INDIREKT

Gibt den durch eine Zeichenkette angegebenen Bezug zurück. Diese Funktion kann auch einen Bereich aus einer entsprechenden Zeichenkette zurückgeben.

Für die Kompatibilität besitzen die Funktionen ADRESSE und INDIREKT nun einen optionalen Parameter, der angibt, ob die R1C1-Schreibweise anstatt der üblichen A1-Schreibweise verwendet werden soll.

In ADRESSE ist dieser Parameter als 4. Parameter eingefügt worden. Der optionale Tabellenname ist nun an die 5. Stelle gerutscht.

Bei INDIREKT wird dieser Parameter als 2. Parameter angehängt.

Bei beiden Funktionen gilt, wenn das Argument mit dem Wert 0 eingefügt wird, dann wird die R1C1-Schreibweise verwendet. Wenn das Argument nicht angegeben wird oder einen Wert ungleich 0 hat, dann wird die A1-Schreibweise verwendet.

Im Falle der R1C1-Schreibweise ergibt ADRESSE das Ausrufezeichen '!' als Trennzeichen für den Tabellennamen und INDIREKT erwartet das Ausrufezeichen als Trennzeichen für Tabellennamen. Beide Funktionen verwenden den Punkt '.' als Trennzeichen im Falle der A1-Schreibweise.

Wenn ein Dokument im Format ODF 1.0/1.1 geöffnet wird und die Funktion ADRESSE einen 4. Parameter als Tabellennamen besitzt, wird dieser an die Stelle des 5. Parameters verschoben. Ein neuer 4. Parameter mit dem Wert 1 wird eingefügt.

Wenn ein Dokument im Format ODF 1.0/1.1 gespeichert wird und für die Funktion ADRESSE ein 4. Parameter festgelegt ist, wird dieser entfernt.

Speichern Sie kein Tabellendokument im alten Format ODF 1.0/1.1, wenn der neue 4. Parameter der Funktion ADRESSE mit dem Wert 0 verwendet wird.

Die Funktion INDIREKT wird ohne Umwandlung im Format ODF 1.0/1.1 gespeichert. Wenn der 2. Parameter vorhanden ist, liefert eine ältere Version von Calc somit einen Fehler für diese Funktion.

### Syntax

INDIREKT(Bezug; A1)

Bezug stellt einen Bezug auf eine Zelle oder einen Bereich dar (in Textform), für den der Inhalt zurückgegeben wird.

Wenn A1 (optional) auf 0 gesetzt ist, wird die R1C1-Schreibweise verwendet. Wenn dieser Parameter fehlt oder einen anderen Wert als 0 hat, wird die A1-Schreibweise verwendet.

Wenn Sie ein Excel Tabellendokument öffnen, welches indirekte Adressen aus Zeichenkettenfunktionen enthält, werden die Tabellenadressen nicht automatisch übersetzt. Zum Beispiel wird die Excel Adresse INDIREKT("[dateiname]tabellenname!"&B1) nicht automatisch in die Calc Adresse INDIREKT("dateiname#tabellenname."&B1) umgewandelt.

### Beispiel

=INDIREKT(A1) entspricht 100, wenn A1 als Bezug C108 enthält und die Zelle C108 den Wert 100 enthält.

=SUMME(INDIREKT("A1:"&ADRESSE(1;3))) summiert die Zellen im Bereich von A1 bis zur Zelle mit der Adresse, die durch Zeile 1 und Spalte 3 definiert ist. Das bedeutet, dass der Bereich A1:C1 summiert wird.

## PIVOTDATENZUORDNEN

Die Funktion PIVOTDATENZUORDNEN ergibt einen Ergebniswert aus einer Pivot-Tabelle. Der Wert wird durch Feldnamen und Elementnamen ausgewählt, sodass der Bezug gültig bleibt, falls sich der Aufbau der Pivot-Tabelle ändert.

### Syntax

Zwei verschiedene Syntax-Varianten können verwendet werden:

PIVOTDATENZUORDNEN(Zielfeld; Pivot-Tabelle; [ Feld 1; Element 1; ... ])

PIVOTDATENZUORDNEN(Pivot-Tabelle; Bedingungen)

Von der zweiten Syntaxvariante wird ausgegangen, wenn genau zwei Parameter vorhanden sind, von denen der erste eine Zelle oder ein Zellbereich ist. In allen anderen Fällen wird von der ersten Syntaxvariante ausgegangen. Der Funktions-Assistent zeigt die erste Syntaxvariante.

### Syntax

Zielfeld ist eine Zeichenkette, die eines der Datenfelder in der Pivot-Tabelle auswählt. Die Zeichenkette kann der Name der Quellspalte oder der Datenfeldname sein, der in der Tabelle angezeigt wird (etwa "Summe - Verkauf").

Pivot-Tabelle ist ein Bezug auf eine Zelle oder einen Zellbereich, dessen Position innerhalb einer Pivot-Tabelle liegt oder der eine Pivot-Tabelle enthält. Wenn der Zellbereich mehrere Pivot-Tabellen enthält, wird die als letztes erstellte verwendet.

Wenn kein Feld n / Element n Paar angegeben ist, wird das Gesamtergebnis der Pivot-Tabelle zurückgegeben. Anderenfalls fügt jedes Paar eine Bedingung hinzu, die das Funktionsergebnis erfüllen muss. Feld n ist ein Feldname der Pivot-Tabelle. Element n ist der Elementname eines Elements dieses Feldes.

Wenn die Pivot-Tabelle nur einen Wert enthält, der alle Bedingungen erfüllt, oder ein Teilergebnis, das alle auf die Bedingung passenden Werte zusammenfasst, dann wird dieses Ergebnis zurückgeliefert. Wenn es gar keinen passenden Wert gibt oder wenn es mehrere Werte gibt, ohne dass eine sie zusammenfassende Funktion existiert, dann wird ein Fehler zurückgeliefert. Diese Regeln beziehen sich auf Ergebnisse, die in der Pivot-Tabelle zu sehen sind.

Wenn die Quelldaten Einträge enthalten, die durch Einstellungen der Pivot-Tabelle verborgen sind, dann werden diese ignoriert. Die Reihenfolge der Feld/Element-Paare ist beliebig. Groß- und Kleinschreibung wird bei Feld- und Elementnamen außer Acht gelassen.

Falls keine Bedingung mittels Seitenfeld angegeben ist, wird der für das Feld ausgewählte Eintrag stillschweigend verwendet. Wenn eine Bedingung mittels Seitenfeld angegeben ist, muss sie zu dem ausgewählten Wert des Seitenfeldes passen, sonst wird ein Fehler zurückgegeben. Seitenfelder sind die Felder oben links in einer Pivot-Tabelle, erstellt durch den Bereich "Seitenfelder" im Dialog Pivot-Tabelle. Aus jedem Seitenfeld kann ein Element (Wert) ausgewählt werden, sodass nur dieses Element in die Berechnung einbezogen wird.

Teilergebnisse aus der Pivot-Tabelle sind nur erreichbar, wenn als Funktion "Automatisch" eingestellt ist (außer wenn die Funktion in der Bedingung angegeben ist, siehe unten Zweite Syntaxvariante).

### Syntax

Pivot-Tabelle hat dieselbe Bedeutung wie in der ersten Syntaxvariante.

Bedingungen ist eine durch Leerzeichen getrennte Liste. Listeneinträge können mit einfachen Anführungszeichen eingeschlossen werden.

Einer der Einträge kann der Datenfeldname sein. Der Datenfeldname kann entfallen, wenn die Pivot-Tabelle nur ein Datenfeld besitzt, anderenfalls muss der Eintrag vorhanden sein.

Jeder der weiteren Parameter beschreibt eine Bedingung in der Form Feld[Element] (wobei [ und ] als Zeichen einzugeben sind) oder nur Element, sofern der Name des Elements eindeutig innerhalb aller in der Pivot-Tabelle verwendeten Felder ist.

Ein Funktionsname kann in Form von Feld[Element;Funktion] hinzugefügt werden, wodurch nur Teilergebnisse abgeglichen werden, die diese Funktion verwenden. Mögliche Funktionsnamen sind Summe, Count, Durchschnitt, Max, Min, Produkt, Count (nur Zahlen), StAbw (Stichprobe), StAbwN (Gesamtheit), Varianz (Stichprobe) und Varianzen (Gesamtheit), ohne Berücksichtigung der Groß- und Kleinschreibung.

## SPALTE

Ergibt die Spaltennummer eines Bezugs. Handelt es sich bei dem Bezug um eine Zelle, dann wird die Spaltennummer der Zelle zurückgegeben; handelt es sich um einen Zellbereich, so werden die entsprechenden Spaltennummern in einer einzeiligen Matrix zurückgegeben, sofern die Formel als Matrixformel eingegeben wurde. Wenn die Funktion SPALTE einen Bereichsbezugsparameter aufweist und nicht als Matrixformel eingesetzt wird, dann wird nur die Spaltennummer der ersten Zelle innerhalb des Bereichs ermittelt.

### Syntax

SPALTE(Bezug)

Bezug ist der Bezug auf einen Zellbereich, dessen Spaltennummern ermittelt werden sollen. Das Argument kann auch eine einzige Zelle sein.

Wird kein Bezug angegeben, wird die Spaltennummer der Zelle ermittelt, in der die Formel eingegeben wird. LibreOffice Calc setzt automatisch den Bezug auf die aktuelle Zelle.

### Beispiel

=SPALTE(A1) entspricht 1. Spalte A ist die erste Spalte in der Tabelle.

=SPALTE(C3:E3) entspricht 3. Spalte C ist die dritte Spalte in der Tabelle.

=SPALTE(D3:G10) ergibt 4, weil Spalte D die vierte Spalte in der Tabelle ist und die Funktion SPALTE nicht als Matrixformel verwendet wird. (In diesem Fall wird der erste Wert der Matrix immer als Ergebnis verwendet.)

{=SPALTE(B2:B7)} und =SPALTE(B2:B7) ergeben 2, weil der Bezug nur Spalte B als zweite Spalte in der Tabelle enthält. Da einspaltige Bereiche nur eine Spaltennummer haben, ist es egal, ob die Formel als Matrixformel verwendet wird oder nicht.

=SPALTE() ergibt 3, wenn die Formel in Spalte C eingegeben wurde.

{=SPALTE(Kaninchen)} ergibt eine einzeilige Matrix (3, 4), wenn "Kaninchen" der benannte Bereich (C1:D3) ist.

## SPALTEN

Ergibt die Anzahl der Spalten eines gegebenen Bezugs.

### Syntax

SPALTEN(Matrix)

Matrix ist der Bezug auf eine Zelle, deren Gesamtanzahl von Spalten gefunden werden soll. Das Argument kann auch eine einzelne Zelle sein.

### Beispiel

=SPALTEN(B5) ergibt 1, weil eine Zelle nur eine Spalte enthält.

=SPALTEN(A1:C5) entspricht 3. Der Bezug umfasst drei Spalten.

=SPALTEN(Kaninchen) ergibt 2, wenn Kaninchen der benannte Bereich (C1:D3) ist.

## SVERWEIS

Senkrechte Suche mit Bezug auf rechts benachbarte Zellen. Diese Funktion prüft, ob ein bestimmter Wert in der ersten Spalte einer Matrix vorhanden ist. Die Funktion gibt dann den Wert in der gleichen Zeile der Spalte zurück, die durch Index benannt ist. Wenn der Parameter Sortiert weggelassen oder auf WAHR oder 1 gesetzt wird, wird angenommen, dass die Daten in aufsteigender Reihenfolge sortiert werden. Wenn dies der Fall ist und das exakte Suchkriterium nicht gefunden wird, wird der letzte Wert, der kleiner als das Kriterium ist, zurückgegeben. Wenn Sortiert auf FALSCH oder Null gesetzt wird, muss eine exakte Übereinstimmung gefunden werden, anderenfalls wird die Fehlermeldung Fehler: Wert nicht verfügbar angezeigt. Demzufolge müssen die Daten bei einem Wert von Null nicht in aufsteigender Reihenfolge sortiert werden.

Die Suche unterstützt auch reguläre Ausdrücke. Sie können zum Beispiel "all.*" eingeben, um die erste Stelle von "all", gefolgt von irgendeinem Zeichen, zu finden. Falls Sie nach Text suchen, der auch ein regulärer Ausdruck ist, müssen Sie jedem Zeichen ein \-Zeichen voranstellen. Sie können die automatische Auswertung regulärer Ausdrücke in LibreOffice - Einstellungen Extras - Optionen... - LibreOffice Calc - Berechnen ein- und ausschalten.

### Syntax

=SVERWEIS(Suchkriterium; Matrix; Index; Sortiert)

Suchkriterium ist der Wert, nach dem in der ersten Spalte der Matrix gesucht wird.

Matrix ist der Bezug, der mindestens so viele Spalten enthalten muss, wie die als Index übergebene Zahl angibt.

Index ist die Nummer der Spalte in der Matrix, die den Wert enthält, der zurückgegeben wird. Die erste Spalte hat die Nummer 1.

Sortiert ist ein optionaler Parameter, der anzeigt, ob die erste Spalte in der Matrix in aufsteigender Reihenfolge sortiert wird. Geben Sie den booleschen Wert FALSCH oder Null ein, wenn die erste Spalte nicht in aufsteigender Reihenfolge sortiert wird. Sortierte Spalten können viel schneller durchsucht werden, und die Funktion gibt immer einen Wert zurück, selbst dann, wenn für den Suchwert keine exakte Übereinstimmung gefunden wurde, wenn er zwischen dem niedrigsten und dem höchsten Wert der sortierten Liste liegt. In unsortierten Listen muss für den Suchwert eine exakte Übereinstimmung gefunden werden. Anderenfalls gibt die Funktion folgende Meldung zurück: Fehler: Wert nicht verfügbar.

Behandeln von leeren Zellen

### Beispiel

Sie können die Nummer eines Gerichts, das Teil einer Speisekarte ist, in Zelle A1 eingeben, woraufhin der Name des Gerichts sofort als Text in der benachbarten Zelle (B1) erscheint. Die Zuweisung der Nummer zum Namen ist in der Matrix D1:E100 enthalten. D1 enthält 100, E1 enthält den Namen Gemüsesuppe und so weiter, wodurch 100 Gerichte erfasst sind. Die Zahlen in Spalte D werden in aufsteigender Reihenfolge sortiert; darum ist der optionale Parameter Sortiert nicht erforderlich.

Fügen Sie in B1 die folgende Formel ein:

=SVERWEIS(A1;D1:E100;2)

Sobald Sie in A1 eine Nummer eingeben, wird in B1 der zugehörige Text angezeigt, der in der zweiten Spalte des Bezugs D1:E100 steht. Geben Sie eine nicht-existente Nummer ein, wird der Text mit der nächstkleineren Nummer angezeigt. Um dies zu verhindern, fügen Sie als letzten Parameter FALSCH in die Formel ein, damit bei Eingabe einer nicht-existenten Nummer eine Fehlermeldung ausgegeben wird.

## TABELLE

Ergibt die Tabellennummer eines Bezugs oder einer Zeichenkette, die einen Tabellennamen darstellt. Ist kein Parameter angegeben, ist das Ergebnis die Tabellennummer der Tabelle, in der die Formel steht.

### Syntax

TABELLE(Bezug)

Bezug ist ein optionaler Parameter und stellt den Bezug auf eine Zelle, einen Bereich oder einen Tabellennamen dar.

### Beispiel

=TABELLE(Tabelle2.A1) ergibt 2, wenn Tabelle2 die zweite Tabelle im Tabellendokument ist.

## TABELLEN

Bestimmt die Anzahl der Tabellen eines Bezugs. Wird kein Parameter angegeben, ergibt es die Anzahl der Tabellen des aktuellen Dokuments.

### Syntax

TABELLEN(Bezug)

Bezug ist der Bezug auf eine Tabelle oder einen Bereich. Dies ist ein optionaler Parameter.

### Beispiel

=TABELLEN(Tabelle1.A1:Tabelle3.G12) ergibt 3, wenn Tabelle1, Tabelle2 und Tabelle3 in der angegebenen Reihenfolge vorhanden sind.

## VERGLEICH

Ergibt die relative Position eines Elements in einer Matrix, das mit einem angegebenen Wert übereinstimmt. Die Funktion liefert die Position des in Suchmatrix gefundenen Werts in Form einer Zahl.

### Syntax

VERGLEICH(Suchkriterium; Suchmatrix; Typ)

Suchkriterium ist der Wert, nach dem in der einzeiligen oder einspaltigen Matrix gesucht werden soll.

Suchmatrix ist der durchsuchte Bezug. Eine Suchmatrix kann eine einzelne Zeile oder Spalte oder ein Teil einer einzelnen Zeile oder Spalte sein.

Typ kann die Werte 1, 0 oder -1 annehmen. Wenn Typ den Wert 1 hat oder dieser optionale Parameter fehlt, wird davon ausgegangen, dass die erste Spalte der Suchmatrix in aufsteigender Reihenfolge sortiert ist. Bei Typ = -1 wird von einer absteigend sortierten Spalte ausgegangen. Dies stimmt mit derselben Funktion in Microsoft Excel überein.

Wenn Typ = 0, dann werden nur exakte Übereinstimmungen gefunden. Wenn das Suchkriterium mehrmals gefunden wird, ergibt die Funktion den Index des ersten übereinstimmenden Werts. Sie können nur dann nach regulären Ausdrücken (falls in den Optionen aktiviert) oder Platzhaltern (falls in den Optionen aktiviert) suchen, wenn Typ = 0 ist.

Wenn Typ = 1 oder wenn der dritte Parameter nicht vorhanden ist, wird der Index des letzten Werts, der kleiner als das Suchkriterium oder gleich groß ist, zurückgegeben. Dies gilt auch dann, wenn die Suchmatrix nicht sortiert ist. Bei Typ = -1 wird der erste Wert, der größer oder gleich groß ist, zurückgegeben.

Die Suche unterstützt auch reguläre Ausdrücke. Sie können zum Beispiel "all.*" eingeben, um die erste Stelle von "all", gefolgt von irgendeinem Zeichen, zu finden. Falls Sie nach Text suchen, der auch ein regulärer Ausdruck ist, müssen Sie jedem Zeichen ein \-Zeichen voranstellen. Sie können die automatische Auswertung regulärer Ausdrücke in LibreOffice - Einstellungen Extras - Optionen... - LibreOffice Calc - Berechnen ein- und ausschalten.

### Beispiel

=VERGLEICH(200;D1:D100) durchsucht den Bereich D1:D100, der nach Spalte D sortiert ist, nach dem Wert 200. Sobald dieser Wert gefunden ist, wird die Nummer der Zeile, in der der Wert gefunden wurde, zurückgegeben. Wenn beim Suchen in der Spalte ein höherer Wert gefunden wird, wird die Nummer der vorhergehenden Zeile zurückgegeben.

## VERSCHIEBUNG

Ergibt den Wert einer Zelle, die um eine bestimmte Anzahl von Zeilen und Spalten gegenüber einer anderen versetzt ist.

### Syntax

VERSCHIEBUNG(Bezug; Zeilen; Spalten; Höhe, Breite)

Bezug ist der Bezug, von dem aus die Funktion nach dem neuen Bezug sucht.

Zeilen ist die Anzahl an Zeilen, die der Bezug nach oben (negativer Wert) oder unten korrigiert wird. Bei 0 wird dieselbe Zeile verwendet.

Spalten ist die Anzahl an Spalten, die der Bezug nach links (negativer Wert) oder rechts korrigiert wird. Bei 0 wird dieselbe Spalte verwendet.

Höhe (optional) ist die vertikale Höhe für einen Bereich, der an der neuen Bezugsposition beginnt.

Breite (optional) ist die horizontale Breite für einen Bereich, der an der neuen Bezugsposition beginnt.

Die Argumente Zeilen und Spalten dürfen weder Null sein noch einen negativen Beginn einer Zeile oder Spalte ergeben.

Die Argumente Höhe und Breite dürfen weder Null noch negativ sein.

In LibreOffice Calc Funktionen dürfen Parameter, die als "optional" gekennzeichnet sind, nur dann ausgelassen werden, wenn ihnen kein weiterer Parameter mehr folgt. So können Sie beispielsweise in einer Funktion mit vier Parametern, von denen die letzten beiden als "optional" gekennzeichnet sind, den Parameter 4 oder die Parameter 3 und 4 auslassen, jedoch nicht den Parameter 3 allein.

### Beispiel

=VERSCHIEBUNG(A1;2;2) ergibt den Wert in Zelle C3 (A1 um zwei Zeilen nach unten und zwei Spalten nach rechts verschoben). Wenn C3 den Wert 100 enthält, gibt diese Funktion den Wert 100 zurück.

=VERSCHIEBUNG(B2:C3;1;1) ergibt einen Bezug auf den Bereich C3:D4 (B2:C3 um eine Zeile nach unten und eine Spalte nach rechts verschoben).

=VERSCHIEBUNG(B2:C3;-1;-1) ergibt einen Bezug auf den Bereich A1:B2 (B2:C3 um eine Zeile nach oben und eine Spalte nach links verschoben).

=VERSCHIEBUNG(B2:C3;0;0;3;4) ergibt einen Bezug auf den Bereich B2:E4 (B2:C3 auf 3 Zeilen und 4 Spalten geändert).

=VERSCHIEBUNG(B2:C3;1;0;3;4) ergibt einen Bezug auf den Bereich B3:E5 (B2:C3 um eine Zeile nach unten verschoben und die Größe auf 3 Zeilen und 4 Spalten geändert).

=SUMME(VERSCHIEBUNG(A1;2;2;5;6)) bestimmt die Summe des Bereichs C3:H7 (A1 um zwei Zeilen nach unten und zwei Spalten nach rechts auf C3 verschoben und die Größe auf 5 Zeilen und 6 Spalten geändert).

Wenn Höhe oder Breite angegeben ist, gibt die Funktion VERSCHIEBUNG einen Bereich zurück und muss folglich als Matrix eingegeben werden. Wenn sowohl Höhe als auch Breite fehlen, wird ein Zellbezug zurückgegeben.

## VERWEIS

Gibt den Inhalt einer Zelle entweder aus einem einzeiligen oder einspaltigen Bereich zurück. Optional wird der zugewiesene Wert (des gleichen Index) in einer anderen Spalte oder Zeile zurückgegeben. Anders als bei SVERWEIS und WVERWEIS können sich der Such- und der Ergebnisvektor in verschiedenen Positionen befinden; sie müssen nicht nebeneinander liegen. Außerdem muss der Suchvektor für den VERWEIS in aufsteigender Reihenfolge sortiert werden, anderenfalls liefert die Suche keine brauchbaren Ergebnisse.

Falls VERWEIS den Suchbegriff nicht finden kann, wird der größte Wert aus dem Suchvektor zurückgegeben, der kleiner oder gleich dem Suchbegriff ist.

Die Suche unterstützt auch reguläre Ausdrücke. Sie können zum Beispiel "all.*" eingeben, um die erste Stelle von "all", gefolgt von irgendeinem Zeichen, zu finden. Falls Sie nach Text suchen, der auch ein regulärer Ausdruck ist, müssen Sie jedem Zeichen ein \-Zeichen voranstellen. Sie können die automatische Auswertung regulärer Ausdrücke in LibreOffice - Einstellungen Extras - Optionen... - LibreOffice Calc - Berechnen ein- und ausschalten.

### Syntax

VERWEIS(Suchkriterium; Suchvektor; Ergebnisvektor)

Suchkriterium ist der Wert, nach dem gesucht werden soll; der Wert wird entweder direkt oder als Bezug eingegeben.

Suchvektor ist der einzeilige oder einspaltige Bereich, der durchsucht werden soll.

Ergebnisvektor ist ein weiterer einzeiliger oder einspaltiger Bereich, aus dem das Ergebnis der Funktion entnommen wird. Das Ergebnis ist die Zelle des Ergebnisvektors mit dem gleichen Index, wie sie im Suchvektor gefunden wurde.

Behandeln von leeren Zellen

### Beispiel

=VERWEIS(A1;D1:D100;F1:F100) durchsucht die entsprechende Zelle im Bereich D1:D100 nach der Zahl, die Sie in A1 eingegeben haben. Für den gefundenen Wert Suchvektor wird der Index bestimmt, beispielsweise die 12. Zelle im Bereich. Dann wird der Inhalt der 12. Zelle des Ergebnisvektors zurückgegeben.

## VORLAGE

Weist der Formelzelle eine Formatvorlage zu. Nach einstellbarer Zeit wird optional eine andere Vorlage zugewiesen. Diese Funktion gibt immer den Wert 0 zurück, so dass Sie die Funktion per Addition zu einer anderen Funktion hinzufügen können, ohne deren Wert zu verändern. Zusammen mit der Funktion AKTUELL können Sie damit eine Zelle in Abhängigkeit vom Wert einfärben, beispielsweise =...+VORLAGE(WENN(AKTUELL()>3;"rot";"grün")) färbt die Zelle mit der Vorlage "rot", wenn der Wert größer 3 ist, sonst mit der Vorlage "grün". Beide Zellformate "rot" und "grün" müssen vorher definiert sein.

### Syntax

VORLAGE("Vorlage"; Zeit; "Vorlage2")

Vorlage ist der Name einer der Zelle zugewiesenen Formatvorlage. Die Namen von Formatvorlagen sind in Anführungszeichen zu setzen.

Zeit ist eine optionale Zeitspanne in Sekunden. Fehlt dieser Parameter, wird die Vorlage nicht nach einer bestimmten Zeit gewechselt.

Vorlage2 ist der optionale Name einer Formatvorlage, die der Zelle nach Verstreichen einer bestimmten Zeit zugewiesen wird. Wenn dieser Parameter nicht vorhanden ist, wird von "Vorgaben" ausgegangen.

In LibreOffice Calc Funktionen dürfen Parameter, die als "optional" gekennzeichnet sind, nur dann ausgelassen werden, wenn ihnen kein weiterer Parameter mehr folgt. So können Sie beispielsweise in einer Funktion mit vier Parametern, von denen die letzten beiden als "optional" gekennzeichnet sind, den Parameter 4 oder die Parameter 3 und 4 auslassen, jedoch nicht den Parameter 3 allein.

### Beispiel

=VORLAGE("Unsichtbar";60;"Standard") formatiert 60 Sekunden lang die Zelle in transparentem Format, nachdem das Dokument neu berechnet oder geladen wurde, anschließend wird das Standardformat zugewiesen. Beide Zellformate müssen vorher definiert werden.

Da VORLAGE() den numerischen Rückgabewert Null hat, wird dieser Rückgabewert an eine Zeichenkette angefügt. Dies kann vermieden werden, indem T() verwendet wird, wie im folgenden Beispiel:

="Text"&T(VORLAGE("eigeneVorlage"))

Ein weiteres Beispiel finden Sie unter AKTUELL().

## WAHL

Gibt den durch einen Index bestimmten Wert aus einer Liste von bis zu 30 Werten zurück.

### Syntax

WAHL(Index; Wert1; ...; Wert30)

Index als Bezug oder Zahl zwischen 1 und 30 gibt an, welcher Wert aus der Liste entnommen werden soll.

Wert 1, Wert 2, ..., Wert 30 ist die Liste der Werte, die jeweils als Bezug auf eine Zelle oder als eigener Wert eingegeben werden.

### Beispiel

=WAHL(A1;B1;B2;B3;"Heute";"Gestern";"Morgen") beispielsweise ergibt den Inhalt der Zelle B2 bei A1 = 2; bei A1 = 4 ergibt die Funktion den Text "Heute".

## WVERWEIS

Sucht einen Wert und einen Bezug auf die Zellen unter dem ausgewählten Bereich. Diese Funktion prüft, ob die erste Zeile einer Matrix einen bestimmten Wert enthält. Sie gibt den Wert dann in einer per Index angegebenen Zeile derselben Spalte der Matrix aus.

Die Suche unterstützt auch reguläre Ausdrücke. Sie können zum Beispiel "all.*" eingeben, um die erste Stelle von "all", gefolgt von irgendeinem Zeichen, zu finden. Falls Sie nach Text suchen, der auch ein regulärer Ausdruck ist, müssen Sie jedem Zeichen ein \-Zeichen voranstellen. Sie können die automatische Auswertung regulärer Ausdrücke in LibreOffice - Einstellungen Extras - Optionen... - LibreOffice Calc - Berechnen ein- und ausschalten.

### Syntax

WVERWEIS(Suchkriterium; Matrix; Index; Sortiert)

Siehe auch: SVERWEIS (Spalten und Zeilen sind vertauscht)

Behandeln von leeren Zellen

## ZEILE

Ergibt die Zeilennummer eines Zellbezugs. Handelt es sich bei dem Bezug um eine Zelle, so ergibt sie die Zeilennummer der Zelle. Ist der Bezug ein Zellbereich, dann ergibt die Funktion die Nummern der entsprechenden Zeilen in einer einspaltigen Matrix, sofern die Formel als Matrixformel eingegeben wurde. Wenn die Funktion ZEILE einen Bereichsbezugsparameter aufweist und nicht als Matrixformel verwendet wird, dann wird nur die Zeilennummer der ersten Zelle innerhalb des Bereichs ermittelt.

### Syntax

ZEILE(Bezug)

Bezug ist der Bezug auf einen Zellbereich, dessen Zeilennummern ermittelt werden sollen. Das Argument kann auch eine einzige Zelle sein.

Wird kein Bezug angegeben, wird die Zeilennummer der Zelle ermittelt, in der die Formel eingegeben wird. LibreOffice Calc setzt automatisch den Bezug auf die aktuelle Zelle.

### Beispiel

=ZEILE(B3) ergibt 3, weil der Bezug auf die dritte Zeile in der Tabelle verweist.

{=ZEILE(D5:D8)} ergibt eine einspaltige Matrix (5, 6, 7, 8), weil der angegebene Bezug die Zeilen 5 bis 8 enthält.

=ZEILE(D5:D8) ergibt 5, weil die Funktion ZEILE nicht als Matrixformel verwendet wird und nur die Zahl der ersten Zeile des Bezugs zurückgegeben wird.

{=ZEILE(A1:E1)} und =ZEILE(A1:E1) ergeben 1, weil der Bezug nur Zeile 1 als erste Zeile in der Tabelle enthält. (Da einzeilige Bereiche nur eine Zeilennummer haben, ist es egal, ob die Formel als Matrixformel verwendet wird oder nicht.)

=ZEILE() ergibt 3, wenn die Formel in Zeile 3 eingegeben wurde.

{=ZEILE(Kaninchen)} ergibt eine einspaltige Matrix (1, 2, 3), wenn "Kaninchen" der benannte Bereich (C1:D3) ist.

## ZEILEN

Ergibt die Anzahl der Zeilen in einem Bezug.

### Syntax

ZEILEN(Matrix)

Matrix ist der Bezug oder der benannte Bereich, dessen Gesamtanzahl von Zeilen bestimmt werden soll.

### Beispiel

=Zeilen(B5) ergibt 1, weil eine Zelle nur eine Zeile enthält.

=ZEILEN(A10:B12) ergibt 3.

=ZEILEN(Kaninchen) ergibt 3, wenn "Kaninchen" der benannte Bereich (C1:D3) ist.

Verwandte Themen

Funktionen nach Kategorie